home *** CD-ROM | disk | FTP | other *** search
/ The PC-SIG Library 10 / The PC-Sig Library - Shareware for the IBM PC and Compatibles (PC-SIG)(Tenth Edition Disks 1-2804)(1991).iso / PC_SIGCD / 01 / 8 / DISK0182.ZIP / TCLOCK.BAS < prev    next >
BASIC Source File  |  1983-02-05  |  25KB  |  501 lines
  1. 1000 ' -----------------------------------------------------------------------
  2. 1010 ' PROGRAM NAME = TCLOCK
  3. 1020 '     FUNCTION = DATE AND TIME DISPLAY ON MONOCHROME
  4. 1030 ' -----------------------------------------------------------------------
  5. 1040 '       AUTHOR = WILLIAM T. VATH
  6. 1050 ' -----------------------------------------------------------------------
  7. 1060 '
  8. 1070 ' To See Instruction Menu, Type Character ?.(INSTRUCTIONS)
  9. 1080 '
  10. 1090 ' To Set Alarm Type Character A.(ALARM)
  11. 1100 '
  12. 1110 ' To Switch From 12 Hour To 24 Hour Display, Type Character M.(MODE)
  13. 1120 '
  14. 1130 ' To Turn Time Change Beep On Or Off, Type Character B.(BEEP)
  15. 1140 '
  16. 1150 ' To Turn Chimes On Or Off, Type Character C.(CHIME)
  17. 1160 '
  18. 1170 ' To Set Date & Time, Type Character S.(SET)
  19. 1180 '
  20. 1190 ' To Cancel The Program And Return To Caller, Hit The ESC Key.
  21. 1200 '
  22. 1210 ' -----------------------------------------------------------------------
  23. 1220 '
  24. 1230 DEFINT A-Z:DIM ALARM$(6),ALDESC$(6):AL$="  :  ":DES$=STRING$(50,32)
  25. 1240 DEF SEG=&H40:POKE &H17,64
  26. 1250 FOR I=1 TO 6:ALARM$(I)=AL$:ALDESC$(I)=DES$:NEXT
  27. 1260 KEY OFF:WIDTH 80:COLOR 7,0:CLS
  28. 1270 D1SAVE=99:D2SAVE=99:D3SAVE=99:D4SAVE=99:TLSAVE=99:TR1SAVE=99:TR2SAVE=99
  29. 1280 SW1$="1":SW2$="0":BP1$="1":BP2$="0":CH1$="0":CH2$="1":AL1$="0"
  30. 1290 ET1$="0":ET2$="1"
  31. 1300 ' -----------------------------------------------------------------------
  32. 1310 '                                                           PRINT BIG BOX
  33. 1320 ' -----------------------------------------------------------------------
  34. 1330 '
  35. 1340 CLS:LOCATE 1,1,0:COLOR 7,0:PRINT CHR$(201)+STRING$(77,205)+CHR$(187);
  36. 1350 FOR I=2 TO 24
  37. 1360 LOCATE I,1:PRINT CHR$(186);:LOCATE I,79:PRINT CHR$(186);
  38. 1370 NEXT
  39. 1380 LOCATE 25,1:PRINT CHR$(200)+STRING$(77,205)+CHR$(188);
  40. 1390 ' -----------------------------------------------------------------------
  41. 1400 '                                                       PRINT CENTER LINE
  42. 1410 ' -----------------------------------------------------------------------
  43. 1420 '
  44. 1430 LOCATE 13,1:COLOR 7,0:PRINT CHR$(204)+STRING$(77,205)+CHR$(185);
  45. 1440 ' -----------------------------------------------------------------------
  46. 1450 '                                                          PRINT DATE BOX
  47. 1460 ' -----------------------------------------------------------------------
  48. 1470 '
  49. 1480 LOCATE 6,2:COLOR 7,0:PRINT CHR$(201)+STRING$(4,205)+CHR$(187);
  50. 1490 LOCATE 7,2:PRINT CHR$(186)+STRING$(4,32)+CHR$(186);
  51. 1500 LOCATE 8,2:PRINT CHR$(200)+STRING$(4,205)+CHR$(188);
  52. 1510 LOCATE 7,3:PRINT "DATE";
  53. 1520 ' -----------------------------------------------------------------------
  54. 1530 '                                                         PRINT DATE DASH
  55. 1540 ' -----------------------------------------------------------------------
  56. 1550 '
  57. 1560 LOCATE 7,36:COLOR 0,7:PRINT STRING$(4,32)
  58. 1570 ' -----------------------------------------------------------------------
  59. 1580 '                                                          PRINT YEAR BOX
  60. 1590 ' -----------------------------------------------------------------------
  61. 1600 '
  62. 1610 LOCATE 9,72:COLOR 7,0:PRINT CHR$(201)+CHR$(205)+CHR$(205)+CHR$(187);
  63. 1620 LOCATE 10,72:PRINT CHR$(186)+CHR$(32)+CHR$(32)+CHR$(186);
  64. 1630 LOCATE 11,72:PRINT CHR$(200)+CHR$(205)+CHR$(205)+CHR$(188);
  65. 1640 ' -----------------------------------------------------------------------
  66. 1650 '                                                          PRINT TIME BOX
  67. 1660 ' -----------------------------------------------------------------------
  68. 1670 '
  69. 1680 LOCATE 18,2:COLOR 7,0:PRINT CHR$(201)+STRING$(4,205)+CHR$(187);
  70. 1690 LOCATE 19,2:PRINT CHR$(186)+STRING$(4,32)+CHR$(186);
  71. 1700 LOCATE 20,2:PRINT CHR$(200)+STRING$(4,205)+CHR$(188);
  72. 1710 LOCATE 19,3:PRINT "TIME";
  73. 1720 ' -----------------------------------------------------------------------
  74. 1730 '                                                        PRINT TIME COLON
  75. 1740 ' -----------------------------------------------------------------------
  76. 1750 '
  77. 1760 LOCATE 17,37:COLOR 0,7:PRINT SPACE$(2):LOCATE 21,37:PRINT SPACE$(2)
  78. 1770 ' -----------------------------------------------------------------------
  79. 1780 '                                                       PRINT SECONDS BOX
  80. 1790 ' -----------------------------------------------------------------------
  81. 1800 '
  82. 1810 LOCATE 21,72:COLOR 7,0:PRINT CHR$(201)+CHR$(205)+CHR$(205)+CHR$(187);
  83. 1820 LOCATE 22,72:PRINT CHR$(186)+CHR$(32)+CHR$(32)+CHR$(186);
  84. 1830 LOCATE 23,72:PRINT CHR$(200)+CHR$(205)+CHR$(205)+CHR$(188);
  85. 1840 ' -----------------------------------------------------------------------
  86. 1850 '                                                                GET DATE
  87. 1860 ' -----------------------------------------------------------------------
  88. 1870 '
  89. 1880 D$=DATE$
  90. 1890 D1$=LEFT$(D$,1):D2$=MID$(D$,2,1):D3$=MID$(D$,4,1):D4$=MID$(D$,5,1)
  91. 1900 D1=VAL(D1$):D2=VAL(D2$):D3=VAL(D3$):D4=VAL(D4$):YR$=RIGHT$(D$,2)
  92. 1910 LOCATE 10,73:COLOR 7,0:PRINT YR$;
  93. 1920 ' -----------------------------------------------------------------------
  94. 1930 '                                                                GET TIME
  95. 1940 ' -----------------------------------------------------------------------
  96. 1950 '
  97. 1960 T$=TIME$:TL$=LEFT$(T$,2)
  98. 1970 TR$=MID$(T$,4,2):TR1$=MID$(T$,4,1):TR2$=MID$(T$,5,1)
  99. 1980 TL=VAL(TL$):TR=VAL(TR$):TR1=VAL(TR1$):TR2=VAL(TR2$)
  100. 1990 IF SW1$="1" THEN 2000 ELSE 2050
  101. 2000 IF TL>11 AND TR>0 THEN LOCATE 15,72:COLOR 1,0:PRINT"P M":GOTO 2020
  102. 2010 LOCATE 15,72:COLOR 1,0:PRINT "A M";
  103. 2020 '
  104. 2030 IF TL>12 THEN TL=TL-12
  105. 2050 '
  106. 2060 IF SW1$="0" THEN LOCATE 15,72:COLOR 1,0:PRINT "MIL";
  107. 2070 SEC$=RIGHT$(T$,2):LOCATE 22,73:COLOR 7,0:PRINT SEC$;:COLOR 0,7
  108. 2080 LOCATE 24,2:COLOR 7,0:IF CH1$="1" THEN PRINT CHR$(14); ELSE PRINT" ";
  109. 2090 LOCATE 24,78:COLOR 7,0:IF BP1$="1" THEN PRINT CHR$(46); ELSE PRINT" ";
  110. 2100 ' -----------------------------------------------------------------------
  111. 2110 '                                                       CHECK ALARM TIMES
  112. 2120 ' -----------------------------------------------------------------------
  113. 2130 '
  114. 2140 AL1$="0"
  115. 2150 TALARM$=LEFT$(T$,5)
  116. 2160 FOR I=1 TO 6
  117. 2170 IF ALARM$(I)="  :  " OR ALARM$(I)="  :" THEN 2180 ELSE AL1$="1"
  118. 2180 IF TALARM$=ALARM$(I) THEN GOTO 5610
  119. 2190 NEXT
  120. 2200 IF AL1$="1" THEN LOCATE 2,2:PRINT CHR$(64);
  121. 2210 ' -----------------------------------------------------------------------
  122. 2220 '                                                   CHECK RESPONSE IF ANY
  123. 2230 ' -----------------------------------------------------------------------
  124. 2240 '
  125. 2250 RESP$=INKEY$
  126. 2260 IF RESP$=CHR$(27) THEN 6000
  127. 2270 IF RESP$="M" THEN SWAP SW1$,SW2$
  128. 2280 IF SW1$="0" THEN CH1$="0":CH2$="1"
  129. 2290 IF RESP$="B" THEN SWAP BP1$,BP2$
  130. 2300 IF RESP$="E" THEN SWAP ET1$,ET2$
  131. 2310 IF ET1$="1" THEN CH1$="0":CH2$="1":BP1$="0":BP2$="1"
  132. 2320 IF RESP$="C" THEN SWAP CH1$,CH2$
  133. 2330 IF CH1$="1" THEN BP1$="0":BP2$="1":SW1$="1":SW2$="0":ET1$="0":ET2$="1"
  134. 2340 IF RESP$="R" THEN CNT1=0:CNT2=0:CNT3=0
  135. 2350 IF RESP$="S" THEN GOTO 4620
  136. 2360 IF RESP$="A" THEN GOTO 4810
  137. 2370 IF RESP$="?" THEN GOTO 5750
  138. 2380 ' -----------------------------------------------------------------------
  139. 2390 '                                                    DISPLAY DATE DIGIT 1
  140. 2400 ' -----------------------------------------------------------------------
  141. 2410 '
  142. 2420 A=3
  143. 2430 IF D1=D1SAVE THEN 2520
  144. 2440 B=10
  145. 2450 IF D1=0 THEN 2480
  146. 2460 GOSUB 4180
  147. 2470 ON D1 GOSUB 3460,3520,3590,3650,3730,3790,3860,3920,4010
  148. 2480 D1SAVE=D1
  149. 2490 ' -----------------------------------------------------------------------
  150. 2500 '                                                    DISPLAY DATE DIGIT 2
  151. 2510 ' -----------------------------------------------------------------------
  152. 2520 '
  153. 2530 IF D2=D2SAVE THEN 2620
  154. 2540 B=25
  155. 2550 GOSUB 4180
  156. 2560 IF D2=0 THEN GOSUB 4080
  157. 2570 ON D2 GOSUB 3460,3520,3590,3650,3730,3790,3860,3920,4010
  158. 2580 D2SAVE=D2
  159. 2590 ' -----------------------------------------------------------------------
  160. 2600 '                                                    DISPLAY DATE DIGIT 3
  161. 2610 ' -----------------------------------------------------------------------
  162. 2620 '
  163. 2630 IF D3=D3SAVE THEN 2720
  164. 2640 B=42
  165. 2650 GOSUB 4180
  166. 2660 IF D3=0 THEN GOSUB 4080
  167. 2670 ON D3 GOSUB 3460,3520,3590,3650,3730,3790,3860,3920,4010
  168. 2680 D3SAVE=D3
  169. 2690 ' -----------------------------------------------------------------------
  170. 2700 '                                                    DISPLAY DATE DIGIT 4
  171. 2710 ' -----------------------------------------------------------------------
  172. 2720 '
  173. 2730 IF D4=D4SAVE THEN 2820
  174. 2740 B=57
  175. 2750 GOSUB 4180
  176. 2760 IF D4=0 THEN GOSUB 4080
  177. 2770 ON D4 GOSUB 3460,3520,3590,3650,3730,3790,3860,3920,4010
  178. 2780 D4SAVE=D4
  179. 2790 ' -----------------------------------------------------------------------
  180. 2800 '                                                    DISPLAY TIME DIGIT 1
  181. 2810 ' -----------------------------------------------------------------------
  182. 2820 '
  183. 2830 A=15
  184. 2840 IF TL=TLSAVE THEN 3030
  185. 2850 IF BP1$="1" THEN 2860 ELSE 2870
  186. 2860 SOUND 3000,2
  187. 2870 B=10
  188. 2880 GOSUB 4180
  189. 2890 IF TL=0 THEN GOTO 2940
  190. 2900 ON TL GOSUB 2940,2940,2940,2940,2940,2940,2940,2940,2940,3460,3460,3460,3460,3460,3460,3460,3460,3460,3460,3520,3520,3520,3520,3520
  191. 2910 ' -----------------------------------------------------------------------
  192. 2920 '                                                    DISPLAY TIME DIGIT 2
  193. 2930 ' -----------------------------------------------------------------------
  194. 2940 '
  195. 2950 B=25
  196. 2960 GOSUB 4180
  197. 2970 IF TL=0 THEN GOSUB 4080
  198. 2980 ON TL GOSUB 3460,3520,3590,3650,3730,3790,3860,3920,4010,4080,3460,3520,3590,3650,3730,3790,3860,3920,4010,4080,3460,3520,3590,3650
  199. 2990 TLSAVE=TL
  200. 3000 ' -----------------------------------------------------------------------
  201. 3010 '                                                    DISPLAY TIME DIGIT 3
  202. 3020 ' -----------------------------------------------------------------------
  203. 3030 '
  204. 3040 IF TR1=TR1SAVE THEN 3130
  205. 3050 B=42
  206. 3060 GOSUB 4180
  207. 3070 IF TR1=0 THEN GOSUB 4080
  208. 3080 ON TR1 GOSUB 3460,3520,3590,3650,3730,3790,3860,3920,4010
  209. 3090 TR1SAVE=TR1
  210. 3100 ' -----------------------------------------------------------------------
  211. 3110 '                                                    DISPLAY ELAPSED TIME
  212. 3120 ' -----------------------------------------------------------------------
  213. 3130 '
  214. 3140 IF ET1$="0" THEN 3210
  215. 3150 '
  216. 3160 IF SEC$=SECHOLD$ THEN 3210
  217. 3170 CNT3=CNT3+1
  218. 3180 IF CNT3>=60 THEN CNT2=CNT2+1:CNT3=0
  219. 3190 IF CNT2>=60 THEN CNT1=CNT1+1:CNT2=0
  220. 3200 SECHOLD$=SEC$
  221. 3210 '
  222. 3220 IF CNT1+CNT2+CNT3=0 THEN LOCATE 2,71:COLOR 7,0:PRINT SPACE$(8):GOTO 3270
  223. 3230 LOCATE 2,71:COLOR 7,0:PRINT USING"##";CNT1;
  224. 3240 LOCATE 2,73:PRINT USING":##";CNT2;
  225. 3250 LOCATE 2,76:PRINT USING":##";CNT3;
  226. 3260 ' -----------------------------------------------------------------------
  227. 3270 '                                                    DISPLAY TIME DIGIT 4
  228. 3280 ' -----------------------------------------------------------------------
  229. 3290 '
  230. 3300 IF TR2=TR2SAVE THEN 1850
  231. 3310 IF BP1$="1" THEN 3320 ELSE 3330
  232. 3320 SOUND 4000,1
  233. 3330 B=57
  234. 3340 GOSUB 4180
  235. 3350 IF TR2=0 THEN GOSUB 4080
  236. 3360 ON TR2 GOSUB 3460,3520,3590,3650,3730,3790,3860,3920,4010
  237. 3370 TR2SAVE=TR2
  238. 3380 IF CH1$="1" AND TR$="15" THEN GOSUB 4270
  239. 3390 IF CH1$="1" AND TR$="30" THEN GOSUB 4330
  240. 3400 IF CH1$="1" AND TR$="45" THEN GOSUB 4400
  241. 3410 IF CH1$="1" AND TR$="00" THEN GOSUB 4490
  242. 3420 GOTO 1850
  243. 3430 ' -----------------------------------------------------------------------
  244. 3440 '                                                       DIGIT SUBROUTINES
  245. 3450 ' -----------------------------------------------------------------------
  246. 3460 ' 1
  247. 3470 LOCATE A+0,B+4:PRINT SPACE$(2);:LOCATE A+1,B+4:PRINT SPACE$(2);
  248. 3480 LOCATE A+2,B+4:PRINT SPACE$(2);:LOCATE A+3,B+4:PRINT SPACE$(2);
  249. 3490 LOCATE A+4,B+4:PRINT SPACE$(2);:LOCATE A+5,B+4:PRINT SPACE$(2);
  250. 3500 LOCATE A+6,B+4:PRINT SPACE$(2);:LOCATE A+7,B+4:PRINT SPACE$(2);
  251. 3510 LOCATE A+8,B+4:PRINT SPACE$(2);:RETURN
  252. 3520 ' 2
  253. 3530 LOCATE A+0,B+0:PRINT SPACE$(9);:LOCATE A+1,B+7:PRINT SPACE$(2);
  254. 3540 LOCATE A+2,B+7:PRINT SPACE$(2);:LOCATE A+3,B+7:PRINT SPACE$(2);
  255. 3550 LOCATE A+4,B+0:PRINT SPACE$(9);:LOCATE A+5,B+0:PRINT SPACE$(2);
  256. 3560 LOCATE A+6,B+0:PRINT SPACE$(2);:LOCATE A+7,B+0:PRINT SPACE$(2);
  257. 3570 LOCATE A+8,B+0:PRINT SPACE$(9);:RETURN
  258. 3580 RETURN
  259. 3590 ' 3
  260. 3600 LOCATE A+0,B+0:PRINT SPACE$(9);:LOCATE A+1,B+7:PRINT SPACE$(2);
  261. 3610 LOCATE A+2,B+7:PRINT SPACE$(2);:LOCATE A+3,B+7:PRINT SPACE$(2);
  262. 3620 LOCATE A+4,B+0:PRINT SPACE$(9);:LOCATE A+5,B+7:PRINT SPACE$(2);
  263. 3630 LOCATE A+6,B+7:PRINT SPACE$(2);:LOCATE A+7,B+7:PRINT SPACE$(2);
  264. 3640 LOCATE A+8,B+0:PRINT SPACE$(9);:RETURN
  265. 3650 ' 4
  266. 3660 LOCATE A+0,B+0:PRINT SPACE$(2);:LOCATE A+0,B+7:PRINT SPACE$(2);
  267. 3670 LOCATE A+1,B+0:PRINT SPACE$(2);:LOCATE A+1,B+7:PRINT SPACE$(2);
  268. 3680 LOCATE A+2,B+0:PRINT SPACE$(2);:LOCATE A+2,B+7:PRINT SPACE$(2);
  269. 3690 LOCATE A+3,B+0:PRINT SPACE$(2);:LOCATE A+3,B+7:PRINT SPACE$(2);
  270. 3700 LOCATE A+4,B+0:PRINT SPACE$(9);:LOCATE A+5,B+7:PRINT SPACE$(2);
  271. 3710 LOCATE A+6,B+7:PRINT SPACE$(2);:LOCATE A+7,B+7:PRINT SPACE$(2);
  272. 3720 LOCATE A+8,B+7:PRINT SPACE$(2);:RETURN
  273. 3730 ' 5
  274. 3740 LOCATE A+0,B+0:PRINT SPACE$(9);:LOCATE A+1,B+0:PRINT SPACE$(2);
  275. 3750 LOCATE A+2,B+0:PRINT SPACE$(2);:LOCATE A+3,B+0:PRINT SPACE$(2);
  276. 3760 LOCATE A+4,B+0:PRINT SPACE$(9);:LOCATE A+5,B+7:PRINT SPACE$(2);
  277. 3770 LOCATE A+6,B+7:PRINT SPACE$(2);:LOCATE A+7,B+7:PRINT SPACE$(2);
  278. 3780 LOCATE A+8,B+0:PRINT SPACE$(9);:RETURN
  279. 3790 ' 6
  280. 3800 LOCATE A+0,B+0:PRINT SPACE$(9);:LOCATE A+1,B+0:PRINT SPACE$(2);
  281. 3810 LOCATE A+2,B+0:PRINT SPACE$(2);:LOCATE A+3,B+0:PRINT SPACE$(2);
  282. 3820 LOCATE A+4,B+0:PRINT SPACE$(9);:LOCATE A+5,B+0:PRINT SPACE$(2);
  283. 3830 LOCATE A+5,B+7:PRINT SPACE$(2);:LOCATE A+6,B+0:PRINT SPACE$(2);
  284. 3840 LOCATE A+6,B+7:PRINT SPACE$(2);:LOCATE A+7,B+0:PRINT SPACE$(2);
  285. 3850 LOCATE A+7,B+7:PRINT SPACE$(2);:LOCATE A+8,B+0:PRINT SPACE$(9);:RETURN
  286. 3860 ' 7
  287. 3870 LOCATE A+0,B+0:PRINT SPACE$(9);:LOCATE A+1,B+7:PRINT SPACE$(2);
  288. 3880 LOCATE A+2,B+7:PRINT SPACE$(2);:LOCATE A+3,B+7:PRINT SPACE$(2);
  289. 3890 LOCATE A+4,B+7:PRINT SPACE$(2);:LOCATE A+5,B+7:PRINT SPACE$(2);
  290. 3900 LOCATE A+6,B+7:PRINT SPACE$(2);:LOCATE A+7,B+7:PRINT SPACE$(2);
  291. 3910 LOCATE A+8,B+7:PRINT SPACE$(2);:RETURN
  292. 3920 ' 8
  293. 3930 LOCATE A+0,B+0:PRINT SPACE$(9);:LOCATE A+1,B+0:PRINT SPACE$(2);
  294. 3940 LOCATE A+1,B+7:PRINT SPACE$(2);:LOCATE A+2,B+0:PRINT SPACE$(2);
  295. 3950 LOCATE A+2,B+7:PRINT SPACE$(2);:LOCATE A+3,B+0:PRINT SPACE$(2);
  296. 3960 LOCATE A+3,B+7:PRINT SPACE$(2);:LOCATE A+4,B+0:PRINT SPACE$(9);
  297. 3970 LOCATE A+5,B+0:PRINT SPACE$(2);:LOCATE A+5,B+7:PRINT SPACE$(2);
  298. 3980 LOCATE A+6,B+0:PRINT SPACE$(2);:LOCATE A+6,B+7:PRINT SPACE$(2);
  299. 3990 LOCATE A+7,B+0:PRINT SPACE$(2);:LOCATE A+7,B+7:PRINT SPACE$(2);
  300. 4000 LOCATE A+8,B+0:PRINT SPACE$(9);:RETURN
  301. 4010 ' 9
  302. 4020 LOCATE A+0,B+0:PRINT SPACE$(9);:LOCATE A+1,B+0:PRINT SPACE$(2);
  303. 4030 LOCATE A+1,B+7:PRINT SPACE$(2);:LOCATE A+2,B+0:PRINT SPACE$(2);
  304. 4040 LOCATE A+2,B+7:PRINT SPACE$(2);:LOCATE A+3,B+0:PRINT SPACE$(2);
  305. 4050 LOCATE A+3,B+7:PRINT SPACE$(2);:LOCATE A+4,B+0:PRINT SPACE$(9);
  306. 4060 LOCATE A+5,B+7:PRINT SPACE$(2);:LOCATE A+6,B+7:PRINT SPACE$(2);
  307. 4070 LOCATE A+7,B+7:PRINT SPACE$(2);:LOCATE A+8,B+0:PRINT SPACE$(9);:RETURN
  308. 4080 ' 0
  309. 4090 LOCATE A+0,B+0:PRINT SPACE$(9);:LOCATE A+1,B+0:PRINT SPACE$(2);
  310. 4100 LOCATE A+1,B+7:PRINT SPACE$(2);:LOCATE A+2,B+0:PRINT SPACE$(2);
  311. 4110 LOCATE A+2,B+7:PRINT SPACE$(2);:LOCATE A+3,B+0:PRINT SPACE$(2);
  312. 4120 LOCATE A+3,B+7:PRINT SPACE$(2);:LOCATE A+4,B+0:PRINT SPACE$(2);
  313. 4130 LOCATE A+4,B+7:PRINT SPACE$(2);:LOCATE A+4,B+4:PRINT SPACE$(1);
  314. 4140 LOCATE A+5,B+0:PRINT SPACE$(2);:LOCATE A+5,B+7:PRINT SPACE$(2);
  315. 4150 LOCATE A+6,B+0:PRINT SPACE$(2);:LOCATE A+6,B+7:PRINT SPACE$(2);
  316. 4160 LOCATE A+7,B+0:PRINT SPACE$(2);:LOCATE A+7,B+7:PRINT SPACE$(2);
  317. 4170 LOCATE A+8,B+0:PRINT SPACE$(9);:RETURN
  318. 4180 ' CLEAR
  319. 4190 COLOR 7,0:LOCATE A+8,B+0:PRINT SPACE$(9);:LOCATE A+7,B+0:PRINT SPACE$(9);
  320. 4200 LOCATE A+6,B+0:PRINT SPACE$(9);:LOCATE A+5,B+0:PRINT SPACE$(9);
  321. 4210 LOCATE A+4,B+0:PRINT SPACE$(9);:LOCATE A+3,B+0:PRINT SPACE$(9);
  322. 4220 LOCATE A+2,B+0:PRINT SPACE$(9);:LOCATE A+1,B+0:PRINT SPACE$(9);
  323. 4230 LOCATE A+0,B+0:PRINT SPACE$(9);:COLOR 0,7:RETURN
  324. 4240 ' -----------------------------------------------------------------------
  325. 4250 '                                              15 MINUTE CHIME SUBROUTINE
  326. 4260 ' -----------------------------------------------------------------------
  327. 4270 '
  328. 4280 SOUND 1000,15:SOUND 32000,1:SOUND 800,15:SOUND 32000,1
  329. 4290 SOUND 900,15:SOUND 32000,1:SOUND 600,15:SOUND 32000,1:RETURN
  330. 4300 ' -----------------------------------------------------------------------
  331. 4310 '                                              30 MINUTE CHIME SUBROUTINE
  332. 4320 ' -----------------------------------------------------------------------
  333. 4330 '
  334. 4340 SOUND 600,15:SOUND 32000,1:SOUND 900,15:SOUND 32000,1:SOUND 1000,15
  335. 4350 SOUND 32000,1:SOUND 800,15:SOUND 32000,5:SOUND 1000,15:SOUND 32000,1
  336. 4360 SOUND 900,15:SOUND 32000,1:SOUND 800,15:SOUND 32000,1:SOUND 600,15:RETURN
  337. 4370 ' -----------------------------------------------------------------------
  338. 4380 '                                              45 MINUTE CHIME SUBROUTINE
  339. 4390 ' -----------------------------------------------------------------------
  340. 4400 '
  341. 4410 SOUND 600,15:SOUND 32000,1:SOUND 900,15:SOUND 32000,1:SOUND 1000,15
  342. 4420 SOUND 32000,1:SOUND 800,15:SOUND 32000,5:SOUND 1000,15:SOUND 32000,1
  343. 4430 SOUND 800,15:SOUND 32000,1:SOUND 900,15:SOUND 32000,1:SOUND 600,15
  344. 4440 SOUND 32000,5:SOUND 600,15:SOUND 32000,1:SOUND 900,15:SOUND 32000,1
  345. 4450 SOUND 1000,15:SOUND 32000,1:SOUND 800,15:RETURN
  346. 4460 ' -----------------------------------------------------------------------
  347. 4470 '                                                ON HOUR CHIME SUBROUTINE
  348. 4480 ' -----------------------------------------------------------------------
  349. 4490 '
  350. 4500 SOUND 1000,15:SOUND 32000,1:SOUND 800,15:SOUND 32000,1:SOUND 900,15
  351. 4510 SOUND 32000,1:SOUND 600,15:SOUND 32000,5:SOUND 600,15:SOUND 32000,1
  352. 4520 SOUND 900,15:SOUND 32000,1:SOUND 1000,15:SOUND 32000,1:SOUND 800,15
  353. 4530 SOUND 32000,5:SOUND 1000,15:SOUND 32000,1:SOUND 900,15:SOUND 32000,1
  354. 4540 SOUND 800,15:SOUND 32000,1:SOUND 600,15:SOUND 32000,5:SOUND 600,15
  355. 4550 SOUND 32000,1:SOUND 900,15:SOUND 32000,1:SOUND 1000,15:SOUND 32000,1
  356. 4560 SOUND 800,15:SOUND 32000,20
  357. 4570 '
  358. 4580 FOR I=1 TO TL:SOUND 400,15:SOUND 32000,15:NEXT:RETURN
  359. 4590 ' -----------------------------------------------------------------------
  360. 4600 '                                              SET DATE & TIME SUBROUTINE
  361. 4610 ' -----------------------------------------------------------------------
  362. 4620 '
  363. 4630 COLOR 7,0:CLS
  364. 4640 LOCATE 2,20:COLOR 0,7:PRINT"    S E T    D A T E    T I M E    "
  365. 4650 LOCATE 5,36:COLOR 7,0:PRINT"CURRENT DATE = ";DATE$
  366. 4660 LOCATE 7,20:INPUT"ENTER NEW DATE - ELSE ENTER--> ",IN$
  367. 4670 IF IN$="" THEN 4680 ELSE DATE$=IN$
  368. 4680 LOCATE 5,36:COLOR 0,7:PRINT"CURRENT DATE = ";DATE$
  369. 4690 LOCATE 10,36:COLOR 7,0:PRINT"CURRENT TIME = ";TIME$
  370. 4700 LOCATE 12,20:INPUT"ENTER NEW TIME - ELSE ENTER--> ",IN$
  371. 4710 IF IN$="" THEN 4720 ELSE TIME$=IN$
  372. 4720 LOCATE 10,36:COLOR 0,7:PRINT"CURRENT TIME = ";TIME$
  373. 4730 LOCATE 15,20:COLOR 7,0:PRINT"IS DATE AND TIME CORRECT ? (Y or N)"
  374. 4740 RESP$=INKEY$:IF RESP$="" THEN 4740
  375. 4750 IF RESP$="Y" THEN 4760 ELSE 4620
  376. 4760 D1SAVE=99:D2SAVE=99:D3SAVE=99:D4SAVE=99:TLSAVE=99:TR1SAVE=99:TR2SAVE=99
  377. 4770 GOTO 1330
  378. 4780 ' -----------------------------------------------------------------------
  379. 4790 '                                                    SET ALARM SUBROUTINE
  380. 4800 ' -----------------------------------------------------------------------
  381. 4810 '
  382. 4820 COLOR 7,0:CLS
  383. 4830 LOCATE 2,20:COLOR 0,7:PRINT"    S E T    A L A R M    T I M E S    "
  384. 4840 LOCATE 4,20:COLOR 7,0:PRINT"CURRENT DATE = ";DATE$
  385. 4850 LOCATE 5,20:PRINT"CURRENT TIME = ";TIME$
  386. 4860 LOCATE 7,10:PRINT"USE 24 HOUR CLOCK TIMES"
  387. 4870 LOCATE 9,15:COLOR 1,0:PRINT"TIMES"
  388. 4880 LOCATE 9,28:PRINT"ALARM DESCRIPTIONS"
  389. 4890 '
  390. 4900 FOR I=11 TO 16:LOCATE I,15:COLOR 7,0:PRINT SPACE$(64);:NEXT
  391. 4910 LOCATE 11,15:COLOR 1,0:PRINT ALARM$(1)
  392. 4920 LOCATE 11,28:PRINT ALDESC$(1)
  393. 4930 LOCATE 12,15:PRINT ALARM$(2)
  394. 4940 LOCATE 12,28:PRINT ALDESC$(2)
  395. 4950 LOCATE 13,15:PRINT ALARM$(3)
  396. 4960 LOCATE 13,28:PRINT ALDESC$(3)
  397. 4970 LOCATE 14,15:PRINT ALARM$(4)
  398. 4980 LOCATE 14,28:PRINT ALDESC$(4)
  399. 4990 LOCATE 15,15:PRINT ALARM$(5)
  400. 5000 LOCATE 15,28:PRINT ALDESC$(5)
  401. 5010 LOCATE 16,15:PRINT ALARM$(6)
  402. 5020 LOCATE 16,28:PRINT ALDESC$(6)
  403. 5030 LOCATE 7,40:COLOR 7,0:PRINT"YOU CAN SET UP TO 6 ALARM TIMES"
  404. 5040 LOCATE 11,15:LINE INPUT"",IN$
  405. 5050 IF IN$="" THEN 5060 ELSE ALARM$(1)=IN$
  406. 5060 LOCATE 11,15:PRINT SPACE$(10)
  407. 5070 LOCATE 11,15:PRINT ALARM$(1)
  408. 5080 LOCATE 11,28:INPUT"",IN$
  409. 5090 IF IN$="" THEN 5100 ELSE ALDESC$(1)=IN$
  410. 5100 LOCATE 11,28:PRINT SPACE$(50)
  411. 5110 LOCATE 11,28:PRINT ALDESC$(1)
  412. 5120 LOCATE 12,15:LINE INPUT"",IN$
  413. 5130 IF IN$="" THEN 5140 ELSE ALARM$(2)=IN$
  414. 5140 LOCATE 12,15:PRINT SPACE$(10)
  415. 5150 LOCATE 12,15:PRINT ALARM$(2)
  416. 5160 LOCATE 12,28:INPUT"",IN$
  417. 5170 IF IN$="" THEN 5180 ELSE ALDESC$(2)=IN$
  418. 5180 LOCATE 12,28:PRINT SPACE$(50)
  419. 5190 LOCATE 12,28:PRINT ALDESC$(2)
  420. 5200 LOCATE 13,15:LINE INPUT"",IN$
  421. 5210 IF IN$="" THEN 5220 ELSE ALARM$(3)=IN$
  422. 5220 LOCATE 13,15:PRINT SPACE$(10)
  423. 5230 LOCATE 13,15:PRINT ALARM$(3)
  424. 5240 LOCATE 13,28:INPUT"",IN$
  425. 5250 IF IN$="" THEN 5260 ELSE ALDESC$(3)=IN$
  426. 5260 LOCATE 13,28:PRINT SPACE$(50)
  427. 5270 LOCATE 13,28:PRINT ALDESC$(3)
  428. 5280 LOCATE 14,15:LINE INPUT"",IN$
  429. 5290 IF IN$="" THEN 5300 ELSE ALARM$(4)=IN$
  430. 5300 LOCATE 14,15:PRINT SPACE$(10)
  431. 5310 LOCATE 14,15:PRINT ALARM$(4)
  432. 5320 LOCATE 14,28:INPUT"",IN$
  433. 5330 IF IN$="" THEN 5340 ELSE ALDESC$(4)=IN$
  434. 5340 LOCATE 14,28:PRINT SPACE$(50)
  435. 5350 LOCATE 14,28:PRINT ALDESC$(4)
  436. 5360 LOCATE 15,15:LINE INPUT"",IN$
  437. 5370 IF IN$="" THEN 5380 ELSE ALARM$(5)=IN$
  438. 5380 LOCATE 15,15:PRINT SPACE$(10)
  439. 5390 LOCATE 15,15:PRINT ALARM$(5)
  440. 5400 LOCATE 15,28:INPUT"",IN$
  441. 5410 IF IN$="" THEN 5420 ELSE ALDESC$(5)=IN$
  442. 5420 LOCATE 15,28:PRINT SPACE$(50)
  443. 5430 LOCATE 15,28:PRINT ALDESC$(5)
  444. 5440 LOCATE 16,15:LINE INPUT"",IN$
  445. 5450 IF IN$="" THEN 5460 ELSE ALARM$(6)=IN$
  446. 5460 LOCATE 16,15:PRINT SPACE$(10)
  447. 5470 LOCATE 16,15:PRINT ALARM$(6)
  448. 5480 LOCATE 16,28:INPUT"",IN$
  449. 5490 IF IN$="" THEN 5500 ELSE ALDESC$(6)=IN$
  450. 5500 LOCATE 16,28:PRINT SPACE$(50)
  451. 5510 LOCATE 16,28:PRINT ALDESC$(6)
  452. 5520 LOCATE 19,20:PRINT"ARE ALL ENTRIES CORRECT ? (Y or N)"
  453. 5530 RESP$=INKEY$:IF RESP$="" THEN 5530
  454. 5540 LOCATE 19,20:PRINT SPACE$(40)
  455. 5550 IF RESP$="Y" THEN 5560 ELSE 4890
  456. 5560 D1SAVE=99:D2SAVE=99:D3SAVE=99:D4SAVE=99:TLSAVE=99:TR1SAVE=99:TR2SAVE=99
  457. 5570 GOTO 1330
  458. 5580 ' -----------------------------------------------------------------------
  459. 5590 '                                                   DISPLAY ALARM ROUTINE
  460. 5600 ' -----------------------------------------------------------------------
  461. 5610 '
  462. 5620 COLOR 7,0:CLS
  463. 5630 LOCATE 2,15:COLOR 0,7:PRINT"             A L A R M             "
  464. 5640 LOCATE 10,15:COLOR 7,0:PRINT ALDESC$(I);
  465. 5650 LOCATE 15,15:COLOR 23,0:PRINT"Press  Any  Key  To  Reset  Alarm";
  466. 5660 '
  467. 5670 SOUND 1000,5:SOUND 32000,5
  468. 5680 RESP$=INKEY$:IF RESP$="" THEN 5660
  469. 5690 D1SAVE=99:D2SAVE=99:D3SAVE=99:D4SAVE=99:TLSAVE=99:TR1SAVE=99:TR2SAVE=99
  470. 5700 ALARM$(I)="  :  ":ALDESC$(I)=STRING$(50,32)
  471. 5710 GOTO 1330
  472. 5720 ' -----------------------------------------------------------------------
  473. 5730 '                                                    INSTRUCTIONS ROUTINE
  474. 5740 ' -----------------------------------------------------------------------
  475. 5750 '
  476. 5760 COLOR 7,0:CLS
  477. 5770 LOCATE 1,10:COLOR 0,7:PRINT"    CLOCK    FUNCTION    CONTROLS    "
  478. 5780 LOCATE 4,10:COLOR 7,0:PRINT"  B = TIME CHANGE BEEP SET ON/OFF"
  479. 5790 LOCATE 6,10:PRINT"  C = CHIMES SET ON/OFF"
  480. 5800 LOCATE 8,10:PRINT"  E = ELAPSED TIME SET ON/OFF"
  481. 5810 LOCATE 10,10:PRINT"  M = CHANGE FROM 12 TO 24 HOUR MODE"
  482. 5820 LOCATE 1,55:COLOR 0,7:PRINT" CURRENT CONDITION ":COLOR 7,0
  483. 5830 LOCATE 4,60:IF BP1$="1" THEN PRINT" ON" ELSE PRINT"OFF"
  484. 5840 LOCATE 6,60:IF CH1$="1" THEN PRINT" ON" ELSE PRINT"OFF"
  485. 5850 LOCATE 8,60:IF ET1$="1" THEN PRINT" ON" ELSE PRINT"OFF"
  486. 5860 LOCATE 10,60:IF SW1$="1" THEN PRINT" 12" ELSE PRINT" 24"
  487. 5870 LOCATE 12,10:PRINT"  A = SET ALARM TIMES AND DESCRIPTIONS"
  488. 5880 LOCATE 14,10:PRINT"  R = RESET ELAPSED TIME"
  489. 5890 LOCATE 16,10:PRINT"  S = SET DATE AND TIME"
  490. 5900 LOCATE 18,10:PRINT"  ? = DISPLAY INSTRUCTIONS"
  491. 5910 LOCATE 20,10:PRINT"ESC = EXIT - RETURN TO SYSTEM MODE"
  492. 5920 LOCATE 24,20:COLOR 23,0:PRINT"Press  Any  Key  To  Continue";
  493. 5930 RESP$=INKEY$:IF RESP$="" THEN 5930
  494. 5940 COLOR 7,0:CLS
  495. 5950 D1SAVE=99:D2SAVE=99:D3SAVE=99:D4SAVE=99:TLSAVE=99:TR1SAVE=99:TR2SAVE=99
  496. 5960 GOTO 1330
  497. 5970 ' -----------------------------------------------------------------------
  498. 5980 '                                                            EXIT ROUTINE
  499. 5990 ' -----------------------------------------------------------------------
  500. 6000 COLOR 7,0:CLS:END
  501.